Forum de la petite hydroélectricité

Code : Tout sélectionner

[code]
const int Eopto=7;             // Affectation entrée optocoupleur signal secteur (broche 7)
const int PotPerMax=0;         // Affectation entrée potentiomètre période maxi ou fréquence mini (broche A0)
const int PotPerMin=1;         // Affectation entrée potentiomètre période mini ou fréquence maxi (broche A1)
const int PotPause=2;          // Affectation entrée potentiomètre temps de pause (broche A2)
const int SPwm=13;             // Affectation sortie signal PWM (broche 13)

unsigned int Pause;            // Temps de pause (ms)
unsigned int PerMax;           // Seuil de période maxi (µs)
unsigned int PerMin;           // Seuil de période mini (µs)
unsigned int Pwm;              // Sortie PMW (0 à 255)

unsigned long Calcul;          // Variable temporaire
unsigned long Periode;         // Période courante (µs)
unsigned long TEoptoBas;       // Durée de l'état bas du signal optocoupleur (µs) 
unsigned long TEoptoHaut;      // Durée de l'état haut du signal optocoupleur (µs)

void setup()
{
pinMode(Eopto,INPUT);          // Déclaration broche optocoupleur
pinMode(SPwm, OUTPUT);         // Déclaration broche PWM
}

void loop()
{
TEoptoHaut = pulseIn(Eopto,HIGH);                                 // Mesure temps à l'état haut
TEoptoBas = pulseIn(Eopto,LOW);                                   // Mesure temps à l'état bas
Periode = TEoptoHaut + TEoptoBas;                                 // Période = temps état haut + temps état bas
Periode = Periode * 2;                                            // L'opto coupleur conduit à chaque demi-alternance (2 photodiodes tête bêche)

PerMin = 1023 - analogRead (PotPerMin);
PerMin = 19950 - (PerMin * 2);                                    // Période mini de 19950 à (19950 - 1023 * 2) = 17954 µs soit Fmax = 50.1 à 55.8 Hz
PerMax = analogRead (PotPerMax);
PerMax = 20050 + (PerMax * 2);                                    // Période maxi de 20050 à (20050 + 1023 * 2) = 22046 µs soit Fmin = 49.9 à 45.2 Hz

Periode = (Periode < 6700)? PerMax : Periode;                     // si la mesure ne se fait pas (Periode à 0) désactivation de la sortie
Periode = (Periode < PerMin)? PerMin : Periode;                   // si la période est inférieure au seuil mini on la rend égale au seuil mini
Periode = (Periode > PerMax)? PerMax : Periode;                   // si la période est supérieure au seuil maxi on la rend égale au seuil maxi

Calcul = 1023-(1023 * (Periode - PerMin) / (PerMax - PerMin));    // Calcul varie de 0 si Periode = PerMax à 1023 si Periode = PerMin
Pwm = Calcul / 4;                                                 // Pwm varie de 0 si Periode = PerMax à 255 si Periode = PerMin

Pause = analogRead (PotPause);                                    // Pause varie de 0 à 1023 * 5 = 5115 ms soit 0 à 5.1 s
delay(Pause * 5);
analogWrite(SPwm, Pwm);                                           // Ecriture de la sortie Pwm
}